Harald Mossige said:
Would sombody mail me a smal file of working asemblerfile for 8048, 10 - 20
lines of assembler code?
I need somting to help me installing and trying out an asembler and to
integrate an programmer.
Thanks.
HM
Maybe this is what you're looking for.
(Use fixed font)
error: jt0 error ; wait for end of current message
wait: jnt0 wait ; wait for start of next message
clk1: jnt1 clk1 ; wait for first clockpuls
eclk1: jt1 eclk1 ; wait for end of first clockpuls
jni zerfon ; leading zero found
jmp error ; no leading zero, go error
zerfon: mov r7,#8 ; init bits counter for data bits
clkd: jnt1 clkd ; wait for next (data) clockpuls
clr c ; init carry for data bit
eclkd: jt1 eclkd ; wait for end of (data) clockpuls
jni shifdat ; data bit is zero so keep carry zero
cpl c ; data bit non-zero so change carry
shifdat: rlc a ; shift data bit in accu
jnt0 error ;
djnz r7,clkd ; repeat for first eight data bits
mov r7,#25 ; init bits counter for skipped bits
clks: jnt1 clks ; wait for next clockpuls
clr f0 ; init f0 for 33th data bit
eclks: jt1 eclks ; wait for end of clockpuls
jni chkerr ; data bit is zero so keep f0 zero
cpl f0 ; data bit non-zero so change f0
chkerr: jnt0 error ;
djnz r7,clks ; repeat until 33th data bit
clkl: jnt1 clkl ; wait for 34th clockpuls
eclkl: jt1 eclkl ; wait for end of 34th clockpuls
jnt0 error ;
clkc: jnt1 clkc ; wait for last=35th clockpuls
eclkc: jnt1 eclkc ; wait for end of last clockpuls
jt0 error ; must be opposite now!
jf0 blat ;
outl p1,a ;
jmp wait ;
blat: outl p2,a ;
jmp wait ;
petrus bitbyter