Maker Pro
Maker Pro

motors start when i touch arduino port

vish

Nov 12, 2016
8
Joined
Nov 12, 2016
Messages
8
hey guys ...
i ve been building a two wheeled balancing robot lately..
the problem is that the motors are working when i touch the silver input of the auduino ... is my arduino a gone case or is there anything i can do .. pls help..
 

(*steve*)

¡sǝpodᴉʇuɐ ǝɥʇ ɹɐǝɥd
Moderator
Jan 21, 2010
25,510
Joined
Jan 21, 2010
Messages
25,510
There are just so many possibilities.

You may have configured the pins as inputs and you are driving mosfets. Any significant charge on your body could turn the mosfets on (or off).

Or you may have programmed your arduino to respond to signals on other pins. Without activating the internal pullups or adding external pullups or pulldowns the input will again be subject to stray voltages.

Or you may have fried it.
 

vish

Nov 12, 2016
8
Joined
Nov 12, 2016
Messages
8
There are just so many possibilities.

You may have configured the pins as inputs and you are driving mosfets. Any significant charge on your body could turn the mosfets on (or off).

Or you may have programmed your arduino to respond to signals on other pins. Without activating the internal pullups or adding external pullups or pulldowns the input will again be subject to stray voltages.

Or you may have fried it.
 

vish

Nov 12, 2016
8
Joined
Nov 12, 2016
Messages
8
There are just so many possibilities.

You may have configured the pins as inputs and you are driving mosfets. Any significant charge on your body could turn the mosfets on (or off).

Or you may have programmed your arduino to respond to signals on other pins. Without activating the internal pullups or adding external pullups or pulldowns the input will again be subject to stray voltages.

Or you may have fried it.


CODE::::


Code:
#include <PID_v1.h>
#include <LMotorController.h>
#include "I2Cdev.h"

#include "MPU6050_6Axis_MotionApps20.h"

#if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
  #include "Wire.h"
#endif


#define LOG_INPUT 0
#define MANUAL_TUNING 0
#define LOG_PID_CONSTANTS 0 //MANUAL_TUNING must be 1
#define MOVE_BACK_FORTH 0

#define MIN_ABS_SPEED 30

//MPU


MPU6050 mpu;

// MPU control/status vars
bool dmpReady = false;  // set true if DMP init was successful
uint8_t mpuIntStatus;  // holds actual interrupt status byte from MPU
uint8_t devStatus;  // return status after each device operation (0 = success, !0 = error)
uint16_t packetSize;  // expected DMP packet size (default is 42 bytes)
uint16_t fifoCount;  // count of all bytes currently in FIFO
uint8_t fifoBuffer[64]; // FIFO storage buffer

// orientation/motion vars
Quaternion q;  // [w, x, y, z]  quaternion container
VectorFloat gravity;  // [x, y, z]  gravity vector
float ypr[3];  // [yaw, pitch, roll]  yaw/pitch/roll container and gravity vector


//PID


#if MANUAL_TUNING
  double kp , ki, kd;
  double prevKp, prevKi, prevKd;
#endif
double originalSetpoint = 174.29;
double setpoint = originalSetpoint;
double movingAngleOffset = 0.3;
double input, output;
int moveState=0; //0 = balance; 1 = back; 2 = forth

#if MANUAL_TUNING
  PID pid(&input, &output, &setpoint, 0, 0, 0, DIRECT);
#else
  PID pid(&input, &output, &setpoint, 70, 240, 1.9, DIRECT);
#endif


//MOTOR CONTROLLER


int ENA = 3;
int IN1 = 4;
int IN2 = 8;
int IN3 = 5;
int IN4 = 7;
int ENB = 6;


LMotorController motorController(ENA, IN1, IN2, ENB, IN3, IN4, 1, 1);


//timers


long time1Hz = 0;
long time5Hz = 0;


volatile bool mpuInterrupt = false;  // indicates whether MPU interrupt pin has gone high
void dmpDataReady()
{
  mpuInterrupt = true;
}


void setup()
{
  // join I2C bus (I2Cdev library doesn't do this automatically)
  #if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
  Wire.begin();
  TWBR = 24; // 400kHz I2C clock (200kHz if CPU is 8MHz)
  #elif I2CDEV_IMPLEMENTATION == I2CDEV_BUILTIN_FASTWIRE
  Fastwire::setup(400, true);
  #endif

  // initialize serial communication
  // (115200 chosen because it is required for Teapot Demo output, but it's
  // really up to you depending on your project)
  Serial.begin(115200);
  while (!Serial); // wait for Leonardo enumeration, others continue immediately

  // initialize device
  Serial.println(F("Initializing I2C devices..."));
  mpu.initialize();

  // verify connection
  Serial.println(F("Testing device connections..."));
  Serial.println(mpu.testConnection() ? F("MPU6050 connection successful") : F("MPU6050 connection failed"));

  // load and configure the DMP
  Serial.println(F("Initializing DMP..."));
  devStatus = mpu.dmpInitialize();

  // supply your own gyro offsets here, scaled for min sensitivity
  mpu.setXGyroOffset(220);
  mpu.setYGyroOffset(76);
  mpu.setZGyroOffset(-85);
  mpu.setZAccelOffset(1788); // 1688 factory default for my test chip

  // make sure it worked (returns 0 if so)
  if (devStatus == 0)
  {
  // turn on the DMP, now that it's ready
  Serial.println(F("Enabling DMP..."));
  mpu.setDMPEnabled(true);

  // enable Arduino interrupt detection
  Serial.println(F("Enabling interrupt detection (Arduino external interrupt 0)..."));
  attachInterrupt(0, dmpDataReady, RISING);
  mpuIntStatus = mpu.getIntStatus();

  // set our DMP Ready flag so the main loop() function knows it's okay to use it
  Serial.println(F("DMP ready! Waiting for first interrupt..."));
  dmpReady = true;

  // get expected DMP packet size for later comparison
  packetSize = mpu.dmpGetFIFOPacketSize();
  
  //setup PID
  
  pid.SetMode(AUTOMATIC);
  pid.SetSampleTime(10);
  pid.SetOutputLimits(-255, 255); 
  }
  else
  {
  // ERROR!
  // 1 = initial memory load failed
  // 2 = DMP configuration updates failed
  // (if it's going to break, usually the code will be 1)
  Serial.print(F("DMP Initialization failed (code "));
  Serial.print(devStatus);
  Serial.println(F(")"));
  }
}


void loop()
{
  // if programming failed, don't try to do anything
  if (!dmpReady) return;

  // wait for MPU interrupt or extra packet(s) available
  while (!mpuInterrupt && fifoCount < packetSize)
  {
  //no mpu data - performing PID calculations and output to motors
  
  pid.Compute();
  motorController.move(output, MIN_ABS_SPEED);
  
  unsigned long currentMillis = millis();

  if (currentMillis - time1Hz >= 1000)
  {
  loopAt1Hz();
  time1Hz = currentMillis;
  }
  
  if (currentMillis - time5Hz >= 5000)
  {
  loopAt5Hz();
  time5Hz = currentMillis;
  }
  }

  // reset interrupt flag and get INT_STATUS byte
  mpuInterrupt = false;
  mpuIntStatus = mpu.getIntStatus();

  // get current FIFO count
  fifoCount = mpu.getFIFOCount();

  // check for overflow (this should never happen unless our code is too inefficient)
  if ((mpuIntStatus & 0x10) || fifoCount == 1024)
  {
  // reset so we can continue cleanly
  mpu.resetFIFO();
  Serial.println(F("FIFO overflow!"));

  // otherwise, check for DMP data ready interrupt (this should happen frequently)
  }
  else if (mpuIntStatus & 0x02)
  {
  // wait for correct available data length, should be a VERY short wait
  while (fifoCount < packetSize) fifoCount = mpu.getFIFOCount();

  // read a packet from FIFO
  mpu.getFIFOBytes(fifoBuffer, packetSize);
  
  // track FIFO count here in case there is > 1 packet available
  // (this lets us immediately read more without waiting for an interrupt)
  fifoCount -= packetSize;

  mpu.dmpGetQuaternion(&q, fifoBuffer);
  mpu.dmpGetGravity(&gravity, &q);
  mpu.dmpGetYawPitchRoll(ypr, &q, &gravity);
  #if LOG_INPUT
  Serial.print("ypr\t");
  Serial.print(ypr[0] * 180/M_PI);
  Serial.print("\t");
  Serial.print(ypr[1] * 180/M_PI);
  Serial.print("\t");
  Serial.println(ypr[2] * 180/M_PI);
  #endif
  input = ypr[1] * 180/M_PI + 180;
  }
}


void loopAt1Hz()
{
#if MANUAL_TUNING
  setPIDTuningValues();
#endif
}


void loopAt5Hz()
{
  #if MOVE_BACK_FORTH
  moveBackForth();
  #endif
}


//move back and forth


void moveBackForth()
{
  moveState++;
  if (moveState > 2) moveState = 0;
  
  if (moveState == 0)
  setpoint = originalSetpoint;
  else if (moveState == 1)
  setpoint = originalSetpoint - movingAngleOffset;
  else
  setpoint = originalSetpoint + movingAngleOffset;
}


//PID Tuning (3 potentiometers)

#if MANUAL_TUNING
void setPIDTuningValues()
{
  readPIDTuningValues();
  
  if (kp != prevKp || ki != prevKi || kd != prevKd)
  {
#if LOG_PID_CONSTANTS
  Serial.print(kp);Serial.print(", ");Serial.print(ki);Serial.print(", ");Serial.println(kd);
#endif

  pid.SetTunings(kp, ki, kd);
  prevKp = kp; prevKi = ki; prevKd = kd;
  }
}


void readPIDTuningValues()
{
  int potKp = analogRead(A0);
  int potKi = analogRead(A1);
  int potKd = analogRead(A2);
  
  kp = map(potKp, 0, 1023, 0, 25000) / 100.0; //0 - 250
  ki = map(potKi, 0, 1023, 0, 100000) / 100.0; //0 - 1000
  kd = map(potKd, 0, 1023, 0, 500) / 100.0; //0 - 5
}
#endif


\* I GOT IT FROM NET .. IS SOMETHING WRONG WITH IT?*\
 
Last edited by a moderator:

(*steve*)

¡sǝpodᴉʇuɐ ǝɥʇ ɹɐǝɥd
Moderator
Jan 21, 2010
25,510
Joined
Jan 21, 2010
Messages
25,510
That is definitely code.

Placing it between code tags would be a good idea.

Have you tried debugging the code yourself?
 

(*steve*)

¡sǝpodᴉʇuɐ ǝɥʇ ɹɐǝɥd
Moderator
Jan 21, 2010
25,510
Joined
Jan 21, 2010
Messages
25,510
I've placed code tags around your code so it's at least readable now.

I don't have time to read all of that code and make sense of it. Perhaps you have a link to where you got it from?

There's clearly some other hardware involved. Do you have exactly the same hardware as used originally, and did you connect it up identically?

What's it supposed to do?
 

vish

Nov 12, 2016
8
Joined
Nov 12, 2016
Messages
8
I've placed code tags around your code so it's at least readable now.

I don't have time to read all of that code and make sense of it. Perhaps you have a link to where you got it from?

There's clearly some other hardware involved. Do you have exactly the same hardware as used originally, and did you connect it up identically?

What's it supposed to do?
It's a two wheeled balancing robot.. Segway mini... The connection are fine.. I put the motor driver n's mpu6050 as I normally would..

Dude.. I just changed my arduino and it's working again just like u said.. It had fired... thanks for ur time man.. Ur awesome
 
Top