N
Nick Pine
- Jan 1, 1970
- 0
Here's a program to calculate angles and spacings of horizontal strip
reflectors that might bounce sun down on to a 4' wide drainback water-
filled poly film duct on an attic floor. The duct might have standard
PV panels underneath. The strip reflectors might be 1" foil-faced
polyiso board, which might have a layer of metalized mylar greased to
the surface for greater reflectivity.
This is a near-vertical Fresnel version of a parabolic north attic roof
that's reflective underneath, behind a steep south transparent attic roof.
Nick
10 PI=4*ATN(1)
20 AXISELD=3'axis elevation above horizon (degrees)
30 AXISEL=PI*AXISELD/180'axis elevation above horizon (radians)
40 FL=4'focal length (feet)
50 HEIGHT=1'strip reflector height (feet)
60 N=6'number of strip reflectors
70 PRINT"strip #","bottom (ft)","top (ft)","spacer (in)","tilt (deg)"
80 PRINT
90 A=ATN(HEIGHT/FL)'initial est angle to focus (rad)
100 FOR STRIP=1 TO N'reflector strip # (from bottom)
110 TILT=(A-AXISEL)/2'reflector tilt from vertical (rad)
120 D=HEIGHT*SIN(TILT)'spacer (feet)
130 TH=TB+HEIGHT*COS(TILT)'upper strip edge height (feet)
140 AH=ATN(TH/(FL-D))'new estimate
150 IF ABS((A-AH)/A)>.001 THEN A=AH:GOTO 110'iterate to 0.1%
160 SPACER=12*D'spacer width behind top of strip (inches)
170 PRINT STRIP,TB,TH,SPACER,180*TILT/PI
180 TB=TH+D*TH/(FL-D)'next bottom edge height (feet)
190 NEXT STRIP
200 CONC=N*HEIGHT/FL'concentration ratio
210 OHB=100*D/FL'overhead sun blocking (%)
220 PRINT
230 PRINT"height=";TH,"conc=";CONC,"ohb=";OHB;"%"
strip # bottom (ft) top (ft) spacer (in) tilt (deg)
1 0 .9951384 1.181832 5.651995
2 1.020259 1.996933 2.576726 12.39952
3 2.110213 3.05942 3.775822 18.3398
4 3.320631 4.239043 4.747493 23.30492
5 4.70433 5.592752 5.508333 27.32439
6 6.317759 7.179152 6.095264 30.52662
height= 7.179152 conc= 1.5 ohb= 12.69847 %
Note the gap between the top edge of each strip and the bottom edge
of the strip above. For instance, strip 4 ends 4.2' above the floor
and strip 5 begins 4.7' above the floor, to avoid shading the bottom
of strip 5 by the top of strip 4. The gap might be painted black.
reflectors that might bounce sun down on to a 4' wide drainback water-
filled poly film duct on an attic floor. The duct might have standard
PV panels underneath. The strip reflectors might be 1" foil-faced
polyiso board, which might have a layer of metalized mylar greased to
the surface for greater reflectivity.
This is a near-vertical Fresnel version of a parabolic north attic roof
that's reflective underneath, behind a steep south transparent attic roof.
Nick
10 PI=4*ATN(1)
20 AXISELD=3'axis elevation above horizon (degrees)
30 AXISEL=PI*AXISELD/180'axis elevation above horizon (radians)
40 FL=4'focal length (feet)
50 HEIGHT=1'strip reflector height (feet)
60 N=6'number of strip reflectors
70 PRINT"strip #","bottom (ft)","top (ft)","spacer (in)","tilt (deg)"
80 PRINT
90 A=ATN(HEIGHT/FL)'initial est angle to focus (rad)
100 FOR STRIP=1 TO N'reflector strip # (from bottom)
110 TILT=(A-AXISEL)/2'reflector tilt from vertical (rad)
120 D=HEIGHT*SIN(TILT)'spacer (feet)
130 TH=TB+HEIGHT*COS(TILT)'upper strip edge height (feet)
140 AH=ATN(TH/(FL-D))'new estimate
150 IF ABS((A-AH)/A)>.001 THEN A=AH:GOTO 110'iterate to 0.1%
160 SPACER=12*D'spacer width behind top of strip (inches)
170 PRINT STRIP,TB,TH,SPACER,180*TILT/PI
180 TB=TH+D*TH/(FL-D)'next bottom edge height (feet)
190 NEXT STRIP
200 CONC=N*HEIGHT/FL'concentration ratio
210 OHB=100*D/FL'overhead sun blocking (%)
220 PRINT
230 PRINT"height=";TH,"conc=";CONC,"ohb=";OHB;"%"
strip # bottom (ft) top (ft) spacer (in) tilt (deg)
1 0 .9951384 1.181832 5.651995
2 1.020259 1.996933 2.576726 12.39952
3 2.110213 3.05942 3.775822 18.3398
4 3.320631 4.239043 4.747493 23.30492
5 4.70433 5.592752 5.508333 27.32439
6 6.317759 7.179152 6.095264 30.52662
height= 7.179152 conc= 1.5 ohb= 12.69847 %
Note the gap between the top edge of each strip and the bottom edge
of the strip above. For instance, strip 4 ends 4.2' above the floor
and strip 5 begins 4.7' above the floor, to avoid shading the bottom
of strip 5 by the top of strip 4. The gap might be painted black.
